Gecko [ armaneco.co.uk ]

Name	Size	Permission	Date
256term.csh	771 B	-rw-r--r--	2022-08-16 18:11
256term.sh	841 B	-rw-r--r--	2022-08-16 18:11
bash_timestamps.sh	69 B	-rw-r--r--	2021-08-24 17:00
checkip.sh	3.99 KB	-rwxr-xr-x	2026-01-19 07:28
colorgrep.csh	196 B	-rw-r--r--	2017-03-24 21:09
colorgrep.sh	201 B	-rw-r--r--	2017-03-24 21:09
colorls.csh	1.7 KB	-rw-r--r--	2020-11-16 18:10
colorls.sh	1.57 KB	-rw-r--r--	2020-11-16 18:10
cpanel-php-composer.sh	548 B	-rwxr-xr-x	2023-11-03 20:50
cpanel-user-commands.sh	376 B	-rw-r--r--	2021-08-24 17:00
csh.local	80 B	-rw-r--r--	2020-09-21 13:07
lang.csh	1.67 KB	-rw-r--r--	2022-08-16 18:11
lang.sh	2.64 KB	-rw-r--r--	2022-08-16 18:11
less.csh	123 B	-rw-r--r--	2024-04-30 16:05
less.sh	121 B	-rw-r--r--	2024-04-30 16:05
locallib.csh	240 B	-rwxr-xr-x	2021-08-24 17:01
locallib.sh	288 B	-rwxr-xr-x	2021-08-24 17:01
sh.local	81 B	-rw-r--r--	2020-09-21 13:07
which2.csh	164 B	-rw-r--r--	2014-01-28 00:17
which2.sh	169 B	-rw-r--r--	2014-01-28 00:17

Rename

# skip everything for non-interactive shells
if (! $?prompt) exit

# color-ls initialization
if ( $?USER_LS_COLORS ) then
  if ( "$USER_LS_COLORS" != "" ) then
     #when USER_LS_COLORS defined do not override user
     #specified LS_COLORS and use them
     goto finish
  endif
endif

alias ll 'ls -l'
alias l. 'ls -d .*'
set COLORS=/etc/DIR_COLORS

if ($?TERM) then
  if ( -e "/etc/DIR_COLORS.256color" ) then
    if ( "`/usr/bin/tput colors`" == "256" ) then
       set COLORS=/etc/DIR_COLORS.256color
    endif
  endif
  if ( -e "/etc/DIR_COLORS.$TERM" ) then
     set COLORS="/etc/DIR_COLORS.$TERM"
  endif
endif
if ( -f ~/.dircolors ) set COLORS=~/.dircolors
if ( -f ~/.dir_colors ) set COLORS=~/.dir_colors
if ($?TERM) then
  if ( -f ~/.dircolors."$TERM" ) set COLORS=~/.dircolors."$TERM"
  if ( -f ~/.dir_colors."$TERM" ) set COLORS=~/.dir_colors."$TERM"
endif
set INCLUDE="`/usr/bin/cat "$COLORS" | /usr/bin/grep '^INCLUDE' | /usr/bin/cut -d ' ' -f2-`"

if ( ! -e "$COLORS" ) exit

set _tmp="`/usr/bin/mktemp .colorlsXXX -q --tmpdir=/tmp`"
#if mktemp fails, exit when include was active, otherwise use $COLORS file
if ( "$_tmp" == '' ) then
  if ( "$INCLUDE" == '' ) then
    eval "`/usr/bin/dircolors -c $COLORS`"
  endif
  goto cleanup
endif

if ( "$INCLUDE" != '' ) /usr/bin/cat "$INCLUDE" >> $_tmp
/usr/bin/grep -v '^INCLUDE' "$COLORS" >> $_tmp

eval "`/usr/bin/dircolors -c $_tmp`"

/usr/bin/rm -f $_tmp

if ( "$LS_COLORS" == '' ) exit
cleanup:
set color_none=`/usr/bin/sed -n '/^COLOR.*none/Ip' < $COLORS`
if ( "$color_none" != '' ) then
   unset color_none
   exit
endif
unset color_none
unset _tmp
unset INCLUDE
unset COLORS

finish:
alias ll 'ls -l --color=auto'
alias l. 'ls -d .* --color=auto'
alias ls 'ls --color=auto'